キースイッチの研究6

gnuplotでアクチュエーション、リリースポイントを表示できるようになったのでメモ。 プレスとリリースのカーブの色分けもできなくはないけど、折り返し地点が0になってあまり美しくないのでまだ不採用。

set terminal png nocrop enhanced size 640,480 medium 
set xlabel "Travel [mm]" 
set ylabel "Force [gf]" 
set datafile separator ","
set key top left
set xtics 0.5
set ytics 10
set grid
set title 'Gateron BOX INK V2 Black'
set output 'switch.png'
prv = 0
plot [0:4.5][0:100] \
'jfc00313.csv' using 1:2 with l lw 2 title 'Press', \
'jfc00313.csv' using 1:(a=abs($3-prv)*$2, prv=$3, a > 0 ? a:-1) with points pt 7 lc 1 lw 3 title 'Actuation/Release', \

f:id:eswai:20220212190132p:plain

これで行けた。なるほど0/0を返すとデータなし扱いになるのか。

set terminal png nocrop enhanced size 640,480 medium 
set xlabel "Travel [mm]" 
set ylabel "Force [gf]" 
set datafile separator ","
set key top left
set xtics 0.5
set ytics 10
set grid
set title 'Gateron BOX INK V2 Black'
set output 'switch.png'
prv = 0
plot [0:4.5][0:100] \
'jfc00315.csv' using 1:2 with l lw 2 lc rgbcolor '#0000CC' title 'Press', \
'jfc00315.csv' using 1:($4>0 ? $2:0/0) with l lw 2 lc rgbcolor '#00AA00' title 'Release', \
'jfc00315.csv' using 1:(a=$3-prv, prv=$3, a!=0 ? $2:0/0):(sprintf("%3.2fmm %3.1fgf", $1, $2)) with labels offset char 0,1 point pt 7 lc rgbcolor '#000000' lw 3 title 'Actuation/Release', \

f:id:eswai:20220212210229p:plain